Ein neuer Griff für den Kühlschrank

Seitdem ich einen 3D Drucker habe, warte ich darauf, dass etwas im Haushalt kaputt geht, um es durch ein 3D gedrucktes Teil zu ersetzen - bisher ohne Erfolg - es ist einfach noch nichts kaputt gegangen.

Dann ergab sich eine Situation am Stammtisch. Schon im Dezember letzten Jahres hat mich Werner angesprochen ob es möglich wäre, einen Kühlschrankgriff mittels 3D Druck zu erneuern.

Mein erster Entwurf war rein aus dem Gefühl heraus konstruiert worden und sollte lediglich eine Machbarkeitsstudie (auch für mich und OpenSCAD) sein. Abgerundete Oberflächen sind mit OpenSCAD nicht gerade trivial zu erstellen. Er bestand aus zwei ausgehöhlten Halbkugeln und einer Griffplatte. Dieser Entwurf kam aber nicht weiter in Betracht, da er zu weit weg vom Original war.

Vor 2 Wochen ist dann der defekte Griff endlich mit zum Stammtisch gebracht worden und konnte vermessen werden. Die Maße habe ich (ganz altmodisch) in ein Skizzenbuch eingetragen und nebenher bereits ein paar Vorstellungen skizziert, wie das Teil einmal aussehen könnte.

Nachdem ich den echten Griff gesehen habe und das Ersatzteil diesem ziemlich nahe kommen soll, habe ich noch am Stammtisch eine neue Konstruktion begonnen.

Die gemessenen Werte werden als Variable in OpenSCAD eingetragen:

oben_l=112.5;
oben_b=46;
oben_h=7;
rundung_r=4;

unten_l=106.5;
unten_b=40;
unten_h=12.5;

innen_l=89;
innen_rundung_d=19;



Im unteren Teil besteht der Griff aus einem Oval geformten Körper mit für die Finger passender Vertiefung. In OpenSCAD formuliert man zwei Zylinder und setzt mit der hull() Funktion eine Hülle darum.

hull()
{
  cylinder(h=unten_h, d=unten_b);
 
  translate([unten_l - unten_b, 0, 0])
    cylinder(h=unten_h, d=unten_b);
}    

Die Griffmulde wird durch ein 8-eckiges Prisma (eigentlich ein Zylinder mit 8 Facetten) erzeugt. Um der Asymetrie des Originals näher zu kommen ist das Prisma um 10° gedreht.

translate([(-unten_b / 4) - 1.5, 0, 20])
 rotate([0, 90, 0])
  rotate([0, 0, 10])
   cylinder(h=3 + (unten_l - unten_b / 2), d=unten_b * 0.9, $fn=8);

 

Die Differenz sieht dann so aus:

Damit ist der untere Teil fertig und steht in OpenSCAD als Modul zur Verfügung.

Der Obere Teil besteht aus einer Platte mit Langloch:

Die Ecken der Platte bekommt man mittels einem Zylinder und der minkowski() Funktion abgerundet.

difference()
{
  minkowski()
  {
    cube([oben_l - 2 * rundung_r, oben_b - 2 * rundung_r, oben_h / 2]);
    cylinder(r=rundung_r, h=oben_h / 2, center=false);
  }
  translate([(innen_rundung_d / 2) - rundung_r + (oben_l - innen_l) / 2, oben_b / 2 - rundung_r, 0])
  hull()
  {
    translate([0, 0, -0.5])
    {
      cylinder(h=oben_h + 1, d=innen_rundung_d);
      translate([innen_l - innen_rundung_d, 0, 0])
       cylinder(h=oben_h + 1, d=innen_rundung_d);
    }
  }
}

 Um die Oberseite der Platte ein wenig rund zu bekommen, kann man die Schnittmenge mit einem großen Zylinder bilden. Nachdem ich ein paar Werte ausprobiert hatte, ergaben 200 mm Durchmesser eine ausgewogene Rundung:

intersection()
{
  translate([-7, 20, -95])   
    rotate([0, 90, 0])
      cylinder(d=200, h=oben_l+5);
  oben();
}

Auch hier ist die Achse des Zylinders ein wenig verschoben um der Asymetrie des Originals näher zu kommen. Auch dieser Teil steht als Modul zur Verfügung.

Zusammengebaut ergeben die beiden Module den fertigen Kühlschrankgriff:

Im Quellcode habe ich auch gleich eine Möglichkeit eingebaut, die Ansicht im Vollschnitt zu erzeugen. Damit erhält man einen Einblick in den Querschnitt des Griffs:

Damit konnte der erste Prototyp gedruckt werden. Dabei ergeben sich weitere Überlegungen. Wenn der Griff so wie abgebildet gedruckt wird, braucht man sowohl außen herum, als auch innen Supportmaterial um die Teile der Platte abzustützen, die überhängen. Nach dem Druck muss das Material entfernt werden - und das kann ziemlich aufwändig werden, wenn es sich zu sehr mit dem eigentlichen Objekt verbindet. Hier sieht man noch Teile davon innen und unten rechts:

Druckt man den Griff genau anders herum benötigt man nur minimalen Support für die Rundung. Ich habe beide Varianten ausprobiert und im Ergebnis ist die zweite besser geworden. Hier sieht man die beiden Prototypen und in der Mitte den kaputten Griff:

Als nächstes kam die Farbauswahl. Von allen Farben die ich von Faberdashery habe, war "Bling Bling Gold" diejenige, die der Holzoptik am Nächsten kam. Daraufhin habe ich dann das Filament bestellt.

Nach ein paar Tagen traf es ein und die beiden Griffe konnten gedruckt werden. Der Empfänger muss allerdings die Oberfläche noch ein wenig abschleifen. Durch den zwar minimalen Support sind die obersten Schichten nicht so schön geworden. Auch die Wölbung ist daran Schuld. Das dürfte durch das Abschleifen aber kompensiert werden.

Weil ich immer mal wieder nach den Preisen gefragt werde, habe ich mir hier auch einmal mit den Kosten beschäftigt. Das Material stammt von Faberdashery aus Manchester. Die Bestellung enthielt eine Spule in weiß sowie die 20m Gold á 0,39£. Die anteiligen Transportkosten liegen bei 2,21£. Macht zusammen umgerechnet 13,76€.

Natürlich kann man hier auch noch eine Rechnung über die benötigte Zeit aufmachen. Abmessen, konstruieren und ausprobieren kostet Zeit. Aber letztlich ist es ein Hobby und da spielt Zeit einerseits keine Rolle und andererseits ist das was man an Erfahrung gewinnt bei einem solchen Projekt eh unbezahlbar.

Inzwischen sind die beiden Ersatzgriffe montiert:

Die Dateien zum Nachdrucken befinden sich hier.